-
Notifications
You must be signed in to change notification settings - Fork 3
/
efar.el
5619 lines (4793 loc) · 210 KB
/
efar.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;;; efar.el --- FAR-like file manager -*- lexical-binding: t; -*-
;; Copyright (C) 2021 Vladimir Suntsov
;; SPDX-License-Identifier: GPL-2.0-or-later
;; Author: "Vladimir Suntsov" <vladimir@suntsov.online>
;; Maintainer: vladimir@suntsov.online
;; Version: 1.33
;; Package-Requires: ((emacs "26.1"))
;; Keywords: files
;; URL: https://github.com/suntsov/efar
;; This package is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3, or (at your option)
;; any later version.
;; This package is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;; This package provides FAR-like file manager with some extended
;; functionality, like file search, directory comparison, etc.
;; To start eFar just type M-x efar.
;; When Efar is called with universal argument (C-u M-x efar),
;; default-directory of actual buffer is automatically opened in left panel.
;; Press <C-e ?> to show buffer with all available key bindings.
;; Use M-x customize to configure numerous eFar parameters.
;;; Code:
(require 'subr-x)
(require 'filenotify)
(require 'dired)
(require 'eshell)
(require 'esh-mode)
(require 'em-dirs)
(require 'shell)
(defconst efar-version 1.33 "Current eFar version number.")
(defvar efar-state nil)
(defvar efar-mouse-down-p nil)
(defvar efar-rename-map nil)
;; general variables for subprocessing
(defvar efar-subprocess-processes '())
(defvar efar-subprocess-manager nil)
(defvar efar-subprocess-server nil)
(defvar efar-subprocess-server-port nil)
(defvar efar-subprocess-clients '())
(defvar efar-subprocess-pending-messages '())
;; variables for file search
(defvar efar-search-results '())
(defvar efar-search-update-results-timer nil)
(defvar efar-search-running-p nil)
(defvar efar-search-last-command-params nil)
(defvar efar-search-history nil)
;; variables for directory compare
(defvar efar-dir-diff-results (make-hash-table :test 'equal))
(defvar efar-dir-diff-last-command-params nil)
(defvar efar-dir-diff-running-p nil)
(defvar efar-dir-diff-update-results-timer nil)
(defvar efar-dir-diff-current-dir nil)
(defvar efar-dir-diff-show-changed-only-p nil)
(defconst efar-dir-diff-comp-params '(:size :hash :owner :group :modes))
(defvar efar-dir-diff-actual-comp-params '(:size :hash :owner :group :modes))
;; variables for archive mode
(defvar efar-archive-current-archive nil)
(defvar efar-archive-current-dir nil)
(defvar efar-archive-files nil)
(defvar efar-archive-current-type nil)
(defvar efar-archive-read-buffer-name nil)
(defvar efar-archive-configuration nil)
(defvar efar-valid-keys-for-modes)
(defvar efar-mode-map)
;;--------------------------------------------------------------------------------
;; eFar customization variables
;;--------------------------------------------------------------------------------
;; GROUPS
(defgroup efar nil
"FAR-like file manager"
:group 'applications)
(defgroup efar-parameters nil
"eFar main customization parameters"
:group 'efar)
(defgroup efar-search-parameters nil
"eFar file search parameters"
:group 'efar-parameters)
(defgroup efar-faces nil
"eFar faces"
:group 'efar)
;; FACES
(defface efar-search-file-link-face
'((t :foreground "black"
:background "snow2"
:bold t
:underline t))
"The face used for representing the link to the file"
:group 'efar-faces)
(defface efar-search-line-link-face
'((t :foreground "black"
:background "ivory"))
"The face used for representing the link to the source code line"
:group 'efar-faces)
;; MAIN PARAMETERS
(eval-and-compile
(defcustom efar-buffer-name "*eFAR*"
"Name for the Efar buffer."
:group 'efar-parameters
:type 'string))
(eval-and-compile
(defcustom efar-shell-buffer-name "*eFAR shell*"
"Name for the Efar shell buffer."
:group 'efar-parameters
:type 'string))
(eval-and-compile
(defcustom efar-batch-buffer-name "*eFAR batch operation*"
"Name for the buffer to perform batch operations."
:group 'efar-parameters
:type 'string))
(defcustom efar-dir-diff-results-buffer-name "*eFar directory comparison results*"
"Name of the buffer to display search results in."
:group 'efar-parameters
:type 'string)
(defcustom efar-state-file-name (expand-file-name ".efar-state" user-emacs-directory)
"Path to the eFar state save file."
:group 'efar-parameters
:type 'string)
(defcustom efar-default-startup-dirs (cons user-emacs-directory user-emacs-directory)
"Default directories shown at startup."
:group 'efar-parameters
:type 'cons)
(defcustom efar-save-state-p t
"Save eFar state when eFar buffer is killed to restore it at next open."
:group 'efar-parameters
:type 'boolean)
(defcustom efar-filter-directories-p nil
"Apply filter to the directories and files (t) or to files only (nil)."
:group 'efar-parameters
:type 'boolean)
(defcustom efar-add-slash-to-directories t
"Add ending / to directories."
:group 'efar-parameters
:type 'boolean)
(defcustom efar-auto-read-directories nil
"Automatically show content of the directory under cursor in other buffer."
:group 'efar-parameters
:type 'boolean)
(defcustom efar-auto-read-files t
"Automatically show content of the file under cursor in other buffer."
:group 'efar-parameters
:type 'boolean)
(defcustom efar-auto-read-file-extensions (list "el" "py" "magik" "txt")
"List of file types (extensions) to be automatically read."
:group 'efar-parameters
:type 'list)
(defcustom efar-auto-read-max-file-size 1048576
"Maximum size in bytes for files which will be automatically read."
:group 'efar-parameters
:type 'integer)
(defcustom efar-max-items-in-directory-history 100
"Maximum number of directories to be stored in directory history."
:group 'efar-parameters
:type 'integer)
(defcustom efar-fast-search-filter-enabled-p t
"Filter out not matching files in fast search mode."
:group 'efar-parameters
:type 'boolean)
(defcustom efar-height-correction 0
"Number of lines by which to shrink eFar panel height.
This might be useful in some cases to avoid problems in eFar displaying."
:group 'efar-parameters
:type 'integer)
(defcustom efar-subprocess-max-processes 8
"Number of subprocesses to use for file search."
:group 'efar-search-parameters
:type 'integer)
(defcustom efar-search-results-buffer-name "*eFar search results*"
"Name of the buffer to display search results in."
:group 'efar-search-parameters
:type 'string)
(defcustom efar-search-default-file-mask "*.el"
"Default file name mask to use for file search."
:group 'efar-search-parameters
:type 'string)
(defcustom efar-subprocess-coding 'iso-latin-1
"Coding system to use for background operations (file search, directory compare)."
:group 'efar-search-parameters
:type 'symbol)
(defcustom efar-search-follow-symlinks-p t
"Follow directory symlinks when searching?"
:group 'efar-search-parameters
:type 'boolean)
;; helper macros and functions
(defmacro efar-with-notification-disabled(&rest body)
"Execute BODY with efar-notifications disabled."
`(let ((file-notifier-left (efar-get :panels :left :file-notifier))
(file-notifier-right (efar-get :panels :right :file-notifier)))
(when (file-notify-valid-p (cdr file-notifier-left))
(efar-remove-notifier :left))
(when (file-notify-valid-p (cdr file-notifier-right))
(efar-remove-notifier :right))
,@body
(efar-setup-notifier (efar-get :panels :left :dir) :left)
(efar-setup-notifier (efar-get :panels :right :dir) :right)))
(defmacro efar-write-enable (&rest body)
"Make eFar buffer writable, execute BODY and then make it back read-only."
`(with-current-buffer ,efar-buffer-name
(read-only-mode -1)
,@body
(read-only-mode 1)))
(defmacro efar-retry-when-error (&rest body)
"Retry BODY until success or user answers 'No'."
`(while
(string=
"error"
(condition-case err
,@body
(error (when
(string= "Yes"
(efar-completing-read
(concat "Error: \"" (error-message-string err) "\". Try again? ")
(list "Yes" "No")))
"error"))))))
(defmacro efar-when-can-execute(&rest body)
"Execute BODY only if command is allowed in current panel mode."
`(progn
(unless (get-buffer-window efar-buffer-name)
(efar nil))
(let ((mode (efar-get :panels (efar-get :current-panel) :mode))
(def (assoc this-command efar-valid-keys-for-modes)))
(if (and def
(not (cl-member mode (cdr def))))
(progn
(efar-set-status (format "Function '%s' is not allowed in mode '%s'" this-command (symbol-name mode)) nil t t) )
,@body))))
(defun efar-split-string-shell-command (string)
"Split STRING (a shell command) into a list of strings.
General shell syntax, like single and double quoting, as well as
backslash quoting, is respected.
Copied of Emacs 28.1 split-string-shell-command function for the
purpose of backward compatibility."
(with-temp-buffer
(insert string)
(let ((comint-file-name-quote-list shell-file-name-quote-list))
(car (shell--parse-pcomplete-arguments)))))
;;--------------------------------------------------------------------------------
;; eFar main functions
;;--------------------------------------------------------------------------------
;;;###autoload
(defun efar (arg &optional reinit? no-switch?)
"Main function to run eFar commander.
When ARG is t open default directory of current buffer.
When REINIT? is t then current eFar state is discarded and it is reinitialized.
When NO-SWITCH? is t then don't switch to eFar buffer."
(interactive "P")
(let
;; if eFar buffer doesn't exist, we need to do initialisation
((need-init? (or reinit? (not (get-buffer efar-buffer-name))))
;; get existing or create new eFar buffer
(efar-buffer (get-buffer-create efar-buffer-name))
;; if eFar is called with prefix argument, then go to default-directory of current buffer
(go-to-dir (when arg default-directory)))
(with-current-buffer efar-buffer
(buffer-disable-undo)
(unless (equal major-mode 'efar-mode)
(efar-mode))
;; do initialisation if necessary and redraw the content of the buffer
(when need-init?
(efar-init)
(efar-set-theme)
;; make search processes
;; we do this in advance to speed up search process
(make-thread 'efar-subprocess-run-processes)
(efar-calculate-window-size)
(efar-calculate-widths)
(efar-go-to-dir (efar-get :panels :left :dir) :left)
(efar-go-to-dir (efar-get :panels :right :dir) :right)
(efar-write-enable
(efar-redraw)))
;; go to default-directory of current buffer if function is called with prefix argument
(when go-to-dir
(efar-go-to-dir go-to-dir :left)
(efar-write-enable (efar-redraw)))
(unless no-switch? (efar-do-suggest-hint)))
(unless (or no-switch?
(equal efar-buffer (current-buffer)))
(switch-to-buffer-other-window efar-buffer))
(efar-write-enable (efar-redraw))))
(defun efar-init (&optional reinit?)
"Set up main eFAR configuration.
This function is executed only once when eFAR buffer is created.
REINIT? is a boolean indicating that configuration should be generated enew."
;; disable cursor
(setq cursor-type nil)
;; if saving/restoring of state is allowed then read state from file
(when (and
efar-save-state-p
(file-exists-p efar-state-file-name))
(efar-read-state))
;; if eFAR state cannot be restored from file (missing or broken file) or saving/restoring of state is disabled
;; then initialize state storage with default values
(when (or reinit?
(null efar-state))
(setf efar-state nil)
(efar-init-state)))
(defun efar-init-state ()
"Initialize state with default values."
(setf efar-state (make-hash-table :test `equal))
;; set directories for both panels
(efar-set (car efar-default-startup-dirs) :panels :left :dir)
(efar-set (cdr efar-default-startup-dirs) :panels :right :dir)
;; make left panel active
(efar-set :left :current-panel)
;; set cursor to the first file for both panels
(efar-set 0 :panels :left :current-pos)
(efar-set 0 :panels :right :current-pos)
(efar-set '() :panels :left :selected)
(efar-set '() :panels :right :selected)
(efar-set 0 :panels :left :start-file-number)
(efar-set 0 :panels :right :start-file-number)
(efar-set nil :fast-search-string)
(efar-set 0 :fast-search-occur)
(efar-set nil :notification-timer)
(efar-set "" :panels :left :file-filter)
(efar-set "" :panels :right :file-filter)
(efar-set nil :panels :left :file-notifier)
(efar-set nil :panels :right :file-notifier)
(efar-set :files :panels :left :mode)
(efar-set :files :panels :right :mode)
(efar-set '() :pending-notifications)
(efar-set nil :panels :left :sort-order)
(efar-set nil :panels :right :sort-order)
(efar-set "Name" :panels :left :sort-function-name)
(efar-set "Name" :panels :right :sort-function-name)
(efar-set :both :mode)
(efar-set nil :column-widths)
(efar-set "Ready" :status)
(efar-set nil :reset-status?)
(efar-set 1 :panels :left :view :files :column-number)
(efar-set '(:short :long :detailed :full) :panels :left :view :files :file-disp-mode)
(efar-set 1 :panels :left :view :dir-hist :column-number)
(efar-set '(:long) :panels :left :view :dir-hist :file-disp-mode)
(efar-set 1 :panels :left :view :file-hist :column-number)
(efar-set '(:long) :panels :left :view :file-hist :file-disp-mode)
(efar-set 1 :panels :left :view :bookmark :column-number)
(efar-set '(:long) :panels :left :view :bookmark :file-disp-mode)
(efar-set 1 :panels :left :view :disks :column-number)
(efar-set '(:long) :panels :left :view :disks :file-disp-mode)
(efar-set 1 :panels :left :view :search :column-number)
(efar-set '(:long) :panels :left :view :search :file-disp-mode)
(efar-set 1 :panels :left :view :dir-diff :column-number)
(efar-set '(:short) :panels :left :view :dir-diff :file-disp-mode)
(efar-set 1 :panels :left :view :archive :column-number)
(efar-set '(:short) :panels :left :view :archive :file-disp-mode)
(efar-set 1 :panels :left :view :search-hist :column-number)
(efar-set '(:short) :panels :left :view :search-hist :file-disp-mode)
(efar-set 1 :panels :right :view :files :column-number)
(efar-set '(:short :long :detailed :full) :panels :right :view :files :file-disp-mode)
(efar-set 1 :panels :right :view :dir-hist :column-number)
(efar-set '(:long) :panels :right :view :dir-hist :file-disp-mode)
(efar-set 1 :panels :right :view :file-hist :column-number)
(efar-set '(:long) :panels :right :view :file-hist :file-disp-mode)
(efar-set 1 :panels :right :view :bookmark :column-number)
(efar-set '(:long) :panels :right :view :bookmark :file-disp-mode)
(efar-set 1 :panels :right :view :disks :column-number)
(efar-set '(:long) :panels :right :view :disks :file-disp-mode)
(efar-set 1 :panels :right :view :search :column-number)
(efar-set '(:long) :panels :right :view :search :file-disp-mode)
(efar-set 1 :panels :right :view :dir-diff :column-number)
(efar-set '(:short) :panels :right :view :dir-diff :file-disp-mode)
(efar-set 1 :panels :right :view :archive :column-number)
(efar-set '(:short) :panels :right :view :archive :file-disp-mode)
(efar-set 1 :panels :right :view :search-hist :column-number)
(efar-set '(:short) :panels :right :view :search-hist :file-disp-mode)
(efar-set nil :last-auto-read-buffer)
(efar-set '() :directory-history)
(efar-set '() :bookmarks)
(efar-set '() :file-history)
(efar-set 0 :splitter-shift)
(efar-set 0 :next-hint-number))
(defun efar-get (&rest keys)
"Get value stored by KEYS."
(let ((value nil))
(mapc
(lambda(key)
(if value
(setf value (gethash key value))
(setf value (gethash key efar-state))))
keys)
value))
(defun efar-set (value &rest keys)
"Store VALUE by KEYS."
(let ((place nil))
(mapc
(lambda(key)
(if place
(setf place (puthash key (gethash key place (make-hash-table :test `equal)) place))
(setf place (puthash key (gethash key efar-state (make-hash-table :test `equal)) efar-state))))
(cl-subseq keys 0 -1))
(puthash (car (cl-subseq keys -1)) value (or place efar-state))))
;;--------------------------------------------------------------------------------
;; file sort functions
;;--------------------------------------------------------------------------------
(defconst efar-sort-functions '(("Name" . efar-sort-files-by-name)
("Date" . efar-sort-files-by-modification-date)
("Extension" . efar-sort-files-by-extension)
("Size" . efar-sort-files-by-size)
("Unsorted" . nil)))
(defun efar-get-sort-function (name)
"Return sort function by NAME."
(cdr (assoc name efar-sort-functions)))
(defun efar-sort-function-names (side)
"Return a list of sort function names.
The name of a function which is currently used for the panel SIDE (or current panel) becomes a first entry in the list."
(let ((current-function-name (efar-get :panels side :sort-function-name)))
(append (list current-function-name)
(cl-remove current-function-name
(mapcar
(lambda(e)
(car e))
efar-sort-functions)
:test 'equal))))
(defun efar-sort-files-by-name (a b)
"Function to sort files A and B by name.
Directories always go before normal files.
Function string< is used for comparing file names.
Case is ignored."
(cond
;; directories go first
((and (cadr a) (not (cadr b)))
t)
((and (not (cadr a)) (cadr b))
nil)
;; entries of same type (directory or usual files) sorted in lexicographic order
(t (string<
(downcase (car a))
(downcase (car b))))))
(defun efar-sort-files-by-modification-date (a b)
"Function to sort files A and B by modification date.
Directories always go before normal files."
(cond
;; directories go first
((and (cadr a) (not (cadr b)))
t)
((and (not (cadr a)) (cadr b))
nil)
;; entries of same type (directory or usual files) sorted by comparing modification date
(t (<
(time-to-seconds (nth 6 a))
(time-to-seconds (nth 6 b))))))
(defun efar-sort-files-by-size (a b)
"Function to sort files A and B by file size.
Directories always go before normal files."
(cond
;; directories go first
((and (cadr a) (not (cadr b)))
t)
((and (not (cadr a)) (cadr b))
nil)
;; entries of same type (directory or usual files) sorted by comparing file size
(t (<
(nth 8 a)
(nth 8 b)))))
(defun efar-sort-files-by-extension (a b)
"Function to sort files A and B by type (extension).
Directories always go before normal files.
Function string< is used for comparing file extensions.
Case is ignored."
(cond
;; directories go first
((and (cadr a) (not (cadr b)))
t)
((and (not (cadr a)) (cadr b))
nil)
;; files sorted by extension (if any) in lexicographic order
(t (string<
(downcase (or (file-name-extension (car a)) ""))
(downcase (or (file-name-extension (car b)) ""))))))
(defun efar-do-change-sorting ()
"Change sorting function and sorting order."
(interactive)
(efar-when-can-execute
(let ((side (efar-get :current-panel)))
(efar-set (efar-completing-read "Sort files by" (efar-sort-function-names side))
:panels side :sort-function-name)
(efar-set (string= (char-to-string 9660) (efar-completing-read "Sort order" (list (char-to-string 9650) (char-to-string 9660) )))
:panels side :sort-order)
(efar-refresh-panel side nil (efar-get-short-file-name (efar-current-file))))))
;;--------------------------------------------------------------------------------
;; file notification functions
;;--------------------------------------------------------------------------------
(defun efar-setup-notifier (dir side)
"Set up file-notify-watch for the directory DIR and register it for panel SIDE."
;; first remove existing file-notify-watch
(efar-remove-notifier side)
(let* ((other-side-notifier (efar-get :panels (efar-other-side side) :file-notifier))
(descriptor
;; if file-notify-watch for given DIR is already registered for other panel and it is valid, use it
(if (and
(string= (car other-side-notifier) dir)
(file-notify-valid-p (cdr other-side-notifier)))
(cdr other-side-notifier)
;; otherwise create new one
(file-notify-add-watch dir '(change attribute-change) 'efar-notification))))
(efar-set (cons dir descriptor) :panels side :file-notifier)))
(defun efar-remove-notifier (side &optional dont-check-other)
"Remove file-notify-watch registered for panel SIDE.
If same watch is registered for other panel, then don't remove the watch, but just unregister it for panel SIDE, unless DONT-CHECK-OTHER is t"
(let ((descriptor (cdr (efar-get :panels side :file-notifier)))
(other-descriptor (cdr (efar-get :panels (efar-other-side side) :file-notifier))))
(when (or dont-check-other (not (equal descriptor other-descriptor)))
(file-notify-rm-watch descriptor))
(efar-set nil :panels side :file-notifier)))
(defun efar-notification (event)
"Callback function triggered when a file EVENT occurs.
It stores notification in the queue and runs timer for 1 second.
Notifications in the queue will be processed only if there are no new notifications within 1 second."
(let ((descriptor (car event))
(event-type (nth 1 event)))
;; for any event except 'stopped
(unless (equal event-type 'stopped)
;; if eFAR buffer exists
(when (get-buffer efar-buffer-name)
;; if there is yet no notifications in the queue for given descriptor
;; add descriptor to the queue
(let ((pending-notifications (efar-get :pending-notifications)))
(unless (member descriptor pending-notifications)
(push descriptor pending-notifications)
(efar-set pending-notifications :pending-notifications)))
;; if there is a running timer, cancel it
(let ((timer (efar-get :notification-timer)))
(when timer (cancel-timer timer))
;; create new timer
(efar-set (run-at-time "1 sec" nil
(lambda()
(efar-process-pending-notifications)))
:notification-timer))))))
(defun efar-process-pending-notifications ()
"Process all pending file notifications."
;; while there are notifications in a queue
(while
;; pop next notification
(let* ((pending-notifications (efar-get :pending-notifications))
(descriptor (prog1
(pop pending-notifications)
(efar-set pending-notifications :pending-notifications))))
(when descriptor
;; if event comes from the watcher registered for left panel directory, refersh left panel
(when (equal descriptor (cdr (efar-get :panels :left :file-notifier)))
(efar-refresh-panel :left))
;; if event comes from the watcher registered for right panel directory, refersh right panel
(when (equal descriptor (cdr (efar-get :panels :right :file-notifier)))
(efar-refresh-panel :right))))))
;;--------------------------------------------------------------------------------
;; save/resore state functions
;;--------------------------------------------------------------------------------
(defun efar-remove-file-state ()
"Remove eFar state file. Could be helpful in case of errors during startup."
(interactive)
(delete-file efar-state-file-name))
(defun efar-save-state ()
"Save eFar state to the state file. Data from this file is used during startup to restore last state."
(efar-do-abort)
(with-temp-file efar-state-file-name
(let ((copy (copy-hash-table efar-state)))
;; clear up data not relevant for saving
(puthash :file-notifier nil (gethash :left (gethash :panels copy)))
(puthash :file-notifier nil (gethash :right (gethash :panels copy)))
(puthash :notification-timer nil copy)
(puthash :pending-notifications () copy)
(puthash :files () (gethash :left (gethash :panels copy)))
(puthash :files () (gethash :right (gethash :panels copy)))
(puthash :selected () (gethash :left (gethash :panels copy)))
(puthash :selected () (gethash :right (gethash :panels copy)))
(puthash :last-auto-read-buffer nil copy)
;; add eFar version tag
(puthash :version efar-version copy)
(print copy (current-buffer)))))
(defun efar-read-state ()
"Read eFar state from the file."
(setf efar-state
(efar-check-state-file-version
(with-temp-buffer
(insert-file-contents efar-state-file-name)
(cl-assert (bobp))
(read (current-buffer))))))
(defun efar-check-state-file-version (state)
"Check version of STATE file and upgrade it if necessary."
(let ((state-version (or (gethash :version state) 0.0)))
(cond
;; if current eFar version matches version stored in state file
;; then we have nothing to do - we use loaded state
((equal efar-version state-version)
(message "eFar state loaded from file %s" efar-state-file-name)
state)
;; else if current version of eFar is lower then version stored in state file
;; we have to skip loading state
((< efar-version state-version)
(message "Version of state file is greater then eFar version. State file loading skipped...")
nil)
;; else if current eFar version is greater then version stored in state file
;; we do "upgrade" of state file
(t
(copy-file efar-state-file-name (concat efar-state-file-name "_" (int-to-string state-version)) 1)
(efar-upgrade-state-file state state-version)))))
(defun efar-upgrade-state-file (state from-version)
"Upgrade state file.
Do necessary changes in STATE in order to switch
from version FROM-VERSION to actual version."
(let ((copy (copy-hash-table state)))
(setq efar-state copy)
(condition-case err
(progn
;; 0.9 -> 1.0
(when (< from-version 1.0)
;; transform :directory-history to keep date
(let ((dir-history (mapcar (lambda(e) (cons (car e) (list (cons :side (cdr e)) (cons :time nil))))
(gethash :directory-history efar-state))))
(puthash :directory-history dir-history efar-state))
;; add file-history
(puthash :file-history '() efar-state)
(efar-set 1 :panels :left :view :file-hist :column-number)
(efar-set '(:long) :panels :left :view :file-hist :file-disp-mode)
(efar-set 1 :panels :right :view :file-hist :column-number)
(efar-set '(:long) :panels :right :view :file-hist :file-disp-mode)
(message "eFar state file upgraded to version 1.0"))
;; 1.12 -> 1.13
(when (< from-version 1.13)
(efar-set '(:short :long :detailed :full) :panels :right :view :files :file-disp-mode)
(efar-set '(:short :long :detailed :full) :panels :left :view :files :file-disp-mode)
(message "eFar state file upgraded to version 1.13"))
;; 1.17 -> 1.18
(when (< from-version 1.18)
(efar-set '() :panels :left :selected)
(efar-set '() :panels :left :selected)
(message "eFar state file upgraded to version 1.17"))
;; 1.20 -> 1.21
(when (< from-version 1.21)
(efar-set 1 :panels :left :view :dir-diff :column-number)
(efar-set '(:short) :panels :left :view :dir-diff :file-disp-mode)
(efar-set 1 :panels :right :view :dir-diff :column-number)
(efar-set '(:short) :panels :right :view :dir-diff :file-disp-mode)
(message "eFar state file upgraded to version 1.21"))
;; 1.23 -> 1.24
(when (< from-version 1.24)
(efar-set 1 :panels :left :view :search-hist :column-number)
(efar-set '(:short) :panels :left :view :search-hist :file-disp-mode)
(efar-set 1 :panels :right :view :search-hist :column-number)
(efar-set '(:short) :panels :right :view :search-hist :file-disp-mode)
(message "eFar state file upgraded to version 1.24"))
;; 1.25 -> 1.26
(when (< from-version 1.26)
(let ((b (get-buffer-create "Efar 1.26")))
(with-current-buffer b
(insert (propertize
"Starting from version 1.26 default eFar key bindings changed according to the Emacs Key Binding Conventions.\nCheck actual key bindings by <C-e ?>.\nSee also Readme at https://github.com/suntsov/efar"
'face '(:foreground "red"))))
(switch-to-buffer-other-window b)))
;; -> 1.32
(when (< from-version 1.32)
(efar-set 1 :panels :left :view :archive :column-number)
(efar-set '(:short) :panels :left :view :archive :file-disp-mode)
(efar-set 1 :panels :right :view :archive :column-number)
(efar-set '(:short) :panels :right :view :archive :file-disp-mode)
(message "eFar state file upgraded to version 1.32")))
(error
(message "Error occured during upgrading state file: %s. State file skipped." (error-message-string err))
(setf efar-state nil)))
efar-state))
;;------------------------------------------------------------------
;; efar file operations
;;------------------------------------------------------------------
(defun efar-do-make-dir ()
"Create new directory."
(interactive)
(efar-when-can-execute
(efar-with-notification-disabled
(let ((new-dir-name (read-string "Input name for new directory: "))
(side (efar-get :current-panel)))
;; try to create a directory
(efar-retry-when-error
(make-directory new-dir-name nil))
;; refresh panel and move selection
(efar-refresh-panel side nil new-dir-name)
;; if other panel displays same directory as current one, refresh it as well
(when (string= (efar-get :panels side :dir) (efar-get :panels (efar-other-side) :dir))
(efar-refresh-panel (efar-other-side)))))))
(defun efar-do-copy ()
"Copy files."
(interactive)
(efar-when-can-execute
(let ((mode (efar-get :panels (efar-get :current-panel) :mode)))
(pcase mode
(:files (efar-copy-or-move-files :copy))))))
;;(:archive (efar-archive-copy-files))))))
(defun efar-do-rename ()
"Rename/move files."
(interactive)
(efar-when-can-execute
(efar-copy-or-move-files :move)))
(defun efar-copy-or-move-files (operation &optional dest)
"Copy or move selected files depending on OPERATION.
When DEST is given then use this path as destination path.
Otherwise ask user where to copy/move files to."
(unwind-protect
(progn
(let ((use-dialog-box nil))
(efar-with-notification-disabled
(let* ((side (efar-get :current-panel))
(todir (let ((todir (efar-get :panels (efar-other-side) :dir)))
(if (file-exists-p todir)
todir
(efar-get :panels side :dir))))
(files (efar-selected-files side nil)))
(when files
(let ((destination (or dest
(read-file-name (if (equal operation :copy)
"Copy selected file(s) to "
"Move selected file(s) to ")
(file-name-as-directory todir)
nil
nil
;;when only one file is selected we add file name to proposed path
(when (equal (length files) 1) (efar-get-short-file-name (car files)))))))
(efar-set-status (if (equal operation :copy)
"Copying files..."
"Moving files..."))
(efar-copy-or-move-files-int (pcase operation
(:copy :copy)
(:move :move)
(:rename :move))
files destination)))
(efar-refresh-panel :left)
(efar-refresh-panel :right))))
(efar-set-status "Ready"))))
(defun efar-copy-or-move-files-int (operation files todir &optional fromdir overwrite?)
"Copy or move (depending on OPERATION) FILES into TODIR.
When FROMDIR is not defined then `default-directory' is used.
OVERWRITE? is a boolean indicating that existing files have to be overwritten.
Existing files can be skipped or overwritten depending on user's choice.
User also can select an option to overwrite all remaining files to not be asked multiple times."
(cl-labels ;; make local recursive function (needed to share variable overwrite? in recursion)
((do-operation (operation files todir fromdir)
;; if FROMDIR is not set, we use default-directory as source directory
(let ((default-directory (if fromdir fromdir default-directory)))
(mapc ;; for each file in FILES
(lambda (f)
;; skip files "." and ".."
(unless (or (string= (car f) ".") (string= (car f) ".."))
;; get new file name in destination folder
(let ((newfile
(if (file-directory-p todir)
(expand-file-name (efar-get-short-file-name f) todir)
todir)))
(cond
;; if file is a real file and doesn't exist in destination folder
((and (not (equal (cadr f) t)) (not (file-exists-p newfile)))
;; we just copy it using elisp function
(if (equal operation :copy)
(efar-retry-when-error (copy-file (car f) newfile))
(efar-retry-when-error (rename-file (car f) newfile nil))))
;; if file is a directory and doesn't exist in destination folder
((and (equal (cadr f) t) (not (file-exists-p newfile)))
;; we just copy directory using elisp function
(if (equal operation :copy)
(efar-retry-when-error (copy-directory (car f) newfile nil nil nil))
(efar-retry-when-error (rename-file (car f) newfile))))
;; if file is a real file and does exist in destination folder
((and (not (equal (cadr f) t)) (file-exists-p newfile))
(progn
;; we ask user what to do (overwrite, not overwrite, overwrite all remaining)
;; if user was already asked before and the answer was "All", we don't ask again
(setf overwrite? (cond
((or (null overwrite?) (string= overwrite? "No") (string= overwrite? "Yes"))
(efar-completing-read (concat "File " newfile " already exists. Overwrite? ") (list "Yes" "No" "All")))
(t overwrite?)))
;; we copy file (overwrite) using elisp function if user approved it
(unless (string= overwrite? "No")
(if (equal operation :copy)
(efar-retry-when-error (copy-file (car f) newfile t nil nil nil))
(efar-retry-when-error (rename-file (car f) newfile t))))))
;; if file is a directory and does exist in destination folder
((and (equal (cadr f) t) (file-exists-p newfile))
;; we call local function recursively
(do-operation operation (directory-files-and-attributes (car f) nil nil t 'string) newfile (expand-file-name (efar-get-short-file-name f) default-directory) )
(when (equal operation :move)
(delete-directory (car f))))))))
files))))
;; call local function first time
(do-operation operation files todir fromdir)) )
(defun efar-completing-read (prompt &optional options)
"Read a string in the minibuffer, with completion.
PROMPT is a string to prompt with.
OPTIONS is a collection with possible answers."
(let* ((completion-ignore-case t)
(options (or options '("Yes" "No")))
(prompt (format "%s (%s)"
prompt
(mapconcat #'identity options " | "))))
(completing-read prompt options nil t nil nil (car options))))
(defun efar-do-delete ()
"Delete files."
(interactive)
(efar-when-can-execute
(let ((mode (efar-get :panels (efar-get :current-panel) :mode)))
(pcase mode
(:files (efar-delete-selected))
(:search (efar-delete-selected))
(:bookmark (efar-delete-bookmark))))))
(defun efar-delete-selected ()
"Delete selected file(s)."
(unwind-protect
(efar-with-notification-disabled
(let* ((side (efar-get :current-panel))
(selected-files (efar-selected-files side nil)))
;; ask user for confirmation
(when (and selected-files (string= "Yes" (efar-completing-read "Delete selected files?")))
;; do the deletion of selected files
(efar-set-status "Deleting files...")
(mapc(lambda (f)
(if (equal (cadr f) t)
(efar-retry-when-error (delete-directory (car f) t))
(efar-retry-when-error (delete-file (car f)))))
selected-files)
(efar-refresh-panel side)
(when (string= (efar-get :panels side :dir) (efar-get :panels (efar-other-side) :dir))
(efar-refresh-panel (efar-other-side)))))))
(efar-set-status "Ready"))
(defun efar-do-set-file-modes ()
"Change file permissions."
(interactive)
(efar-when-can-execute
(unwind-protect
(efar-with-notification-disabled
(let* ((side (efar-get :current-panel))
(selected-files (efar-selected-files side nil)))
(when selected-files
(let ((modes (read-file-modes)))
(efar-set-status "Setting mode for selected files...")
(mapc (lambda (f)
(efar-retry-when-error (set-file-modes (car f) modes)))
selected-files))